Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00044_ListMgmt.ls

Text File | 2004-07-11 | 1.7 KB | 73 lines

--
-- ListMgmt
--

-- manage several list functions.
-- all operations are generic.


property ancestor


on new me
  set ancestor = new (script "FileStructTools")
  return me
end


on destruct me
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end


-- check to see properties in a list have corresponding properties in a second list:

on checkPropMatches me, lst1, lst2
  if not ilk (lst1, #proplist) then return 0
  if not ilk (lst2, #proplist) then return 0

  -- cycle through the first list checking all of its props against the props of a second list:
  repeat with p = 1 to count (lst1)
    set p1 = getPropAt (lst1, p)
    if voidP (getaProp (lst2, p1)) then
      put "prop" && QUOTE & p1 & QUOTE && "could not be found in list two."  -- put the property
      return 0
    end if

  end repeat

  return 1
end


-- check to see if properties in a list have corresponding properties in a second list.
-- return the first list after cutting out non-matching properties:

on returnPropMatchList me, lst1, lst2
  if not ilk (lst1, #proplist) then return 0
  if not ilk (lst2, #proplist) then return 0
  set returnLst = [:]

  set num = count (lst1)
  -- cycle through the first list checking all of its props against the props of a second list:
  repeat with i = num down to 1

    -- get the prop at the current position:
    set prop = getPropAt (lst1, i)

    -- if the prop exists in lst2 then add the current prop and value to the returnLst:
    if not voidP (getaProp (lst2, prop)) then
      addProp (returnLst, prop, getAt (lst1, i))
    end if

  end repeat

  if not count (returnLst) then
    put "There were no matches between list 1 and list 2."
    return 0
  else
    return returnLst
  end if
end